Reworked BDD naming macro and R# template

I’ve been using a BDD macro based on the one JP Boodhoo published for getting more descriptive test names along with a R# template so that I can type “test” + tab, type the test name (with spaces) and then hit Alt+- and voila – BDD style test names.

This worked well for a while until some point where R# started to do autocompletion on the test name as I typed (for instance, typing ‘Check that blah is not null’ often ended up as ‘Check that blah is NotImplementedException null’). That was OK though after a quick rework of the R# template and macro so R# wraps the test name in quotes which the macro then removes.

But R# doesn’t format the end result as well (the method braces don’t indent correctly) and this bugged me for a while.

So, a quick change to the macro and the R# template and now it’s much more smooth. Typing ‘tests’ + tab and R# outputs public class “FIXTURENAME” (with fixturename highlighted and ready to type over). Type out the name of the fixture, Alt+- and the macro replaces spaces, puts in the [TestFixture] attribute, drops in the opening and closed braces and puts the caret right where I want it. Sweet.

Do the same with ‘test’ + tab, type test name, Alt+- and you get the same for a test. Extra sweet.

This is the BDD macro:

Imports System
Imports System.Windows.Forms
Imports EnvDTE
Imports EnvDTE80
Imports System.Diagnostics
  
Public Module CodeEditor
    Private Const INDENT_SIZE As Integer = 4
  
    Public Sub ReplaceSpacesInTestNameWithUnderscores()
        If DTE.ActiveDocument Is Nothing Then Return
        Dim wrCS As Boolean = DTE.Properties("TextEditor", "CSharp").Item("WordWrap").Value
  
        Try
            DTE.Properties("TextEditor", "CSharp").Item("WordWrap").Value = False
            Dim selection As TextSelection = CType(DTE.ActiveDocument.Selection(), EnvDTE.TextSelection)
            Dim textPoint As TextPoint = CType(selection.ActivePoint, TextPoint)
            Dim line As Integer = textPoint.Line
            Dim offset As Integer = textPoint.LineCharOffset
            Dim index As Integer
  
            selection.SelectLine()
            If selection.Text = "" Then Return
  
            Dim methodIndex As Integer = selection.Text.IndexOf("public void ")
            Dim classIndex As Integer = selection.Text.IndexOf("public class ")
  
            If (methodIndex < 0 AndAlso classIndex < 0) Then
                selection.MoveToLineAndOffset(line, offset)
                Return
            End If
  
            index = CType(IIf(methodIndex >= 0, methodIndex, classIndex), Integer)
  
            If methodIndex >= 0 Then
                HandleTestMethod(selection, index)
            Else
                HandleTestClass(selection, index)
            End If
        Catch ex As Exception
            MsgBox(ex.Message)
        Finally
            DTE.Properties("TextEditor", "CSharp").Item("WordWrap").Value = wrCS
        End Try
    End Sub
  
    Private Sub HandleTestClass(ByVal selection As TextSelection, ByVal index As Integer)
        Dim whiteSpace As String = GetWhiteSpace(selection, index)
        HandleTestNameFormatting(selection, "public class ", index)
        AddAttribute(selection, index, "[TestFixture]", whiteSpace)
        AddBraces(selection, index, whiteSpace)
    End Sub
  
    Private Sub HandleTestMethod(ByVal selection As TextSelection, ByVal index As Integer)
        Dim whiteSpace As String = GetWhiteSpace(selection, index)
        HandleTestNameFormatting(selection, "public void ", index)
        AddAttribute(selection, index, "[Test]", whiteSpace)
        AddBraces(selection, index, whiteSpace)
    End Sub
  
    Private Sub AddAttribute(ByVal selection As TextSelection, ByVal index As Integer, ByVal attribute As String, ByVal whiteSpace As String)
        selection.LineUp()
        selection.SelectLine()
        If selection.Text.Trim <> attribute Then
            selection.Insert(selection.Text & whiteSpace & attribute & vbCrLf)
        End If
        selection.LineDown()
    End Sub
  
    Private Function AddIndent(ByVal spacer As Char) As String
        Return String.Empty.PadRight(INDENT_SIZE, spacer)
    End Function
  
    Private Sub AddBraces(ByVal selection As TextSelection, ByVal index As Integer, ByVal whiteSpace As String)
        selection.SelectLine()
        If selection.Text.Trim <> "{" Then
            selection.Insert(String.Format("{0}{4}{1}{0}{2}{1}{0}{5}{1}{3}", whiteSpace, vbCrLf, AddIndent(whiteSpace(0)), selection.Text, "{", "}")) ' & whiteSpace & AddIndent(whiteSpace(0)) & vbCrLf & "}" & vbCrLf)
            selection.LineUp()
            selection.LineUp()
            selection.LineUp()
            selection.EndOfLine()
        Else
            selection.LineUp()
            selection.EndOfLine()
        End If
    End Sub
  
    Private Function GetWhiteSpace(ByVal selection As TextSelection, ByVal index As Integer) As String
        Return selection.Text.Substring(0, index)
    End Function
  
    Private Sub HandleTestNameFormatting(ByVal selection As TextSelection, ByVal prefix As String, ByVal index As Integer)
        Dim whiteSpace As String = GetWhiteSpace(selection, index)
        prefix = whiteSpace + prefix
        Dim description As String = selection.Text.Replace(prefix, String.Empty).Trim
        If description(0) = """" Then
            Dim lastQuote As Integer = description.LastIndexOf("""")
            If lastQuote = 0 Then
                description = description.Substring(1)
            Else
                Dim endOfDescription As String = description.Substring(lastQuote + 1)
                description = description.Substring(1, lastQuote - 1) + endOfDescription
            End If
        End If
        Dim text As String = prefix + description.Replace(" ", "_").Replace("'", "_") + vbCrLf
        selection.Delete()
        selection.Insert(text)
        selection.LineUp()
    End Sub
End Module

For the ReSharper templates, open up the live templates and add a template called ‘tests’ with the body of template as below:

public class "$FIXTURENAME$"

And then another one called ‘test’ with the body as

public void "$TESTNAME$"()

Mark both of these as available for C# only (or if for VB.Net, adjust the template body for the VB equivalent), and for the ‘test’ one, mark this as available only where a method declaration is allowed.

That’s it. Now you can get into the flow of typing ‘test’ TAB ‘name of test’ Alt+- and then typing in the test itself.

Reworked BDD naming macro and R# template

Pages

Archives

Categories

Tags

No comments yet